Because the thread was closed, I am opening a new one.

I've done exactly what you are attempting to do. It's very straightforward.

I have an abstract WindowMediator for my Window class (which extends Sprite) and then I create concrete WindowMediators that extend WindowMediator. The abstract has a protected var window:Window and in the onRegister of the concrete mediator, I set window = the injected concrete view.

public class WindowMediator extends Mediator implements IMediator {

protected var window:Window;

public function WindowMediator() 
{
  super();
}
override public function onRegister():void 
{
  eventMap.mapListener(window, Event.CLOSE, onWindowClose, Event);
  eventMap.mapListener(window, Event.ACTIVATE, onWindowActivate, Event);
  eventMap.mapListener(window, Event.DEACTIVATE, onWindowDeactivate, Event);
  eventMap.mapListener(window, Event.ADDED_TO_STAGE, onAddedToStage, Event);
  eventMap.mapListener(window, NativeWindowBoundsEvent.RESIZE, onWindowBounds, NativeWindowBoundsEvent);
  eventMap.mapListener(window, NativeWindowBoundsEvent.MOVE, onWindowBounds, NativeWindowBoundsEvent);
  eventMap.mapListener(window, SystemControlsEvent.CLOSE_WINDOW, onSystemControlClose, SystemControlsEvent);
  eventMap.mapListener(window, SystemControlsEvent.MAXIMIZE_WINDOW, onSystemControlMaximize, SystemControlsEvent);
  eventMap.mapListener(window, SystemControlsEvent.MINIMIZE_WINDOW, onSystemControlMinimize, SystemControlsEvent);
  eventMap.mapListener(window, SystemControlsEvent.RESTORE_WINDOW, onSystemControlRestore, SystemControlsEvent);
  super.onRegister();
}
protected function onAddedToStage(event:Event):void
{
  // initialization
}
protected function onWindowClose(event:Event):void
{
  var owner:Window = (window is ModalWindow) ? ModalWindow(window).owner : null;
  dispatch(new WindowLifeEvent(WindowLifeEvent.DESTROY, null, window.uid, owner));
}
protected function onWindowActivate(event:Event):void
{
  dispatch(new ApplicationWindowEvent(ApplicationWindowEvent.ACTIVATE, window.uid));
}
protected function onWindowDeactivate(event:Event):void
{
  dispatch(new ApplicationWindowEvent(ApplicationWindowEvent.DEACTIVATE, window.uid));
}
protected function onWindowBounds(event:NativeWindowBoundsEvent):void
{
  dispatch(new ApplicationWindowEvent(ApplicationWindowEvent.BOUNDS, window.uid, event.afterBounds));
}
protected function onSystemControlClose(event:SystemControlsEvent):void
{
  window.nativeWindow.close();
}
protected function onSystemControlMaximize(event:SystemControlsEvent):void
{
  window.nativeWindow.maximize();
}
protected function onSystemControlMinimize(event:SystemControlsEvent):void
{
  window.nativeWindow.minimize();
}
protected function onSystemControlRestore(event:SystemControlsEvent):void
{
  window.nativeWindow.restore();
}

}

public class PanelWindowMediator extends WindowMediator implements IMediator {

[Inject]
public var model:PanelModel;
[Inject]
public var panelWindow:PanelWindow;

public function PanelWindowMediator() 
{
  super();
}
override public function onRegister():void 
{
  window = panelWindow;
  panelWindow.panel = model.getPanel(window.uid);
  super.onRegister();
}
override protected function onWindowClose(event:Event):void 
{
  model.closeWindow(panelWindow.panel);
  super.onWindowClose(event);
}

}